Contract Address Details

// File: pox-smart-contract/Models.sol


pragma solidity ^0.5.17;

/**
 * Copyright (C) 2018, 2019, 2020 Ethernity HODL UG
 *
 * This file is part of ETHERNITY PoX SC.
 *
 * ETHERNITY PoE SC is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as
 * published by the Free Software Foundation, either version 3 of the
 * License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Affero General Public License for more details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */

library Models {

    /*
    * used for storing multiple data
    */
    struct Metadata {
        string key;
        string value;
    }

    struct Order {
        uint8 instance;
        address dproc;
        address downer;
        address processor;
        address placedBy;
        uint dpRequest;
        uint doRequest;
        uint timeout;
        mapping(uint => Metadata) metadata;
        uint metadataSize;
        string result;
        uint price;
        OrderStatus status;
    }

    struct DPRequest {
        address dproc;
        uint8 cpuRequest;
        uint8 memoryRequest;
        uint8 storageRequest;
        uint8 bandwidthRequest;
        uint16 duration; //--timeout
        uint8 minPrice;
        uint32 createdAt;
        uint8 price;
        string Metadata1;
        string Metadata2;
        string Metadata3;
        string Metadata4;
        mapping(uint => Metadata) metadata;
        uint metadataSize;
        RequestStatus status;
    }

    struct DORequest {
        address downer;
        // CPU number
        uint8 cpuRequest;
        // Memory in GB
        uint8 memoryRequest;
        // Storage in GB
        uint8 storageRequest;
        uint8 bandwidthRequest;
        uint16 duration;
        uint8 instances;

        uint8 bookedInstances;
        uint32 createdAt;

        uint8 maxPrice;
        uint32 tokens;

        string Metadata1;
        string Metadata2;
        string Metadata3;
        string Metadata4;
        mapping(uint => Metadata) metadata;
        uint metadataSize;
        RequestStatus status;

    }

    enum OrderStatus{
        OPEN,
        PROCESSING,
        CLOSED,
        CANCELED
    }

    enum RequestStatus{
        AVAILABLE,
        BOOKED,
        CANCELED
    }
}

// File: pox-smart-contract/Owned.sol


pragma solidity ^0.5.17;

// ----------------------------------------------------------------------------
// 'FIXED' 'Example Fixed Supply Token' token contract
//
// Symbol      : FIXED
// Name        : Example Fixed Supply Token
// Total supply: 1,000,000.000000000000000000
// Decimals    : 18
//
// Enjoy.
//
// (c) BokkyPooBah / Bok Consulting Pty Ltd 2017. The MIT Licence.
// ----------------------------------------------------------------------------

// ----------------------------------------------------------------------------
// Owned contract
// ----------------------------------------------------------------------------
contract Owned {
    address public owner;
    address public newOwner;

    event OwnershipTransferred(address indexed _from, address indexed _to);

    constructor() public {
        owner = msg.sender;
    }

    modifier onlyOwner {
        require(msg.sender == owner);
        _;
    }

    function transferOwnership(address _newOwner) public onlyOwner {
        newOwner = _newOwner;
    }
    function acceptOwnership() public {
        require(msg.sender == newOwner);
        emit OwnershipTransferred(owner, newOwner);
        owner = newOwner;
        newOwner = address(0);
    }
}

// File: pox-smart-contract/Delegated.sol

pragma solidity ^0.5.17;

/**
 * Copyright (C) 2018, 2019, 2020 Ethernity HODL UG
 *
 * This file is part of ETHERNITY PoX SC.
 *
 * ETHERNITY PoE SC is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as
 * published by the Free Software Foundation, either version 3 of the
 * License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Affero General Public License for more details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */


contract Delegated is Owned {
    address public callerAddress;

    event ProxyTransferred(address indexed _from, address indexed _to);

    constructor() public {
        callerAddress = msg.sender;
    }

    modifier onlyDelegate {
        require(msg.sender == callerAddress);
        _;
    }

    function transferProxy(address _newProxy) public onlyOwner {
        callerAddress = _newProxy;
    }
}

// File: pox-smart-contract/StandardToken.sol


pragma solidity ^0.5.17;


// ----------------------------------------------------------------------------
// 'FIXED' 'Example Fixed Supply Token' token contract
//
// Symbol      : FIXED
// Name        : Example Fixed Supply Token
// Total supply: 1,000,000.000000000000000000
// Decimals    : 18
//
// Enjoy.
//
// (c) BokkyPooBah / Bok Consulting Pty Ltd 2017. The MIT Licence.
// ----------------------------------------------------------------------------


// ----------------------------------------------------------------------------
// Safe maths
// ----------------------------------------------------------------------------
library SafeMath {
    function add(uint a, uint b) internal pure returns (uint c) {
        c = a + b;
        require(c >= a);
    }
    function sub(uint a, uint b) internal pure returns (uint c) {
        require(b <= a);
        c = a - b;
    }
    function mul(uint a, uint b) internal pure returns (uint c) {
        c = a * b;
        require(a == 0 || c / a == b);
    }
    function div(uint a, uint b) internal pure returns (uint c) {
        require(b > 0);
        c = a / b;
    }
}


// ----------------------------------------------------------------------------
// ERC Token Standard #20 Interface
// https://github.com/ethereum/EIPs/blob/master/EIPS/eip-20-token-standard.md
// ----------------------------------------------------------------------------
contract ERC20Interface {
    function totalSupply() public view returns (uint);
    function balanceOf(address tokenOwner) public view returns (uint balance);
    function allowance(address tokenOwner, address spender) public view returns (uint remaining);
    function transfer(address to, uint tokens) public returns (bool success);
    function approve(address spender, uint tokens) public returns (bool success);
    function transferFrom(address from, address to, uint tokens) public returns (bool success);

    event Transfer(address indexed from, address indexed to, uint tokens);
    event Approval(address indexed tokenOwner, address indexed spender, uint tokens);
}


// ----------------------------------------------------------------------------
// Contract function to receive approval and execute function in one call
//
// Borrowed from MiniMeToken
// ----------------------------------------------------------------------------
contract ApproveAndCallFallBack {
    function receiveApproval(address from, uint256 tokens, address token, bytes memory data) public;
}



// ----------------------------------------------------------------------------
// ERC20 Token, with the addition of symbol, name and decimals and an
// initial fixed supply
// ----------------------------------------------------------------------------
contract StandardToken is ERC20Interface, Delegated {
    using SafeMath for uint;

    string public symbol;
    string public  name;
    uint8 public decimals;
    uint public _totalSupply;

    mapping(address => uint) balances;
    mapping(address => mapping(address => uint)) allowed;


    // ------------------------------------------------------------------------
    // Constructor
    // ------------------------------------------------------------------------
    constructor() public {
        symbol = "FIXED";
        name = "Example Fixed Supply Token";
        decimals = 18;
        _totalSupply = 1000000 * 10**uint(decimals);
        balances[owner] = _totalSupply;
        emit Transfer(address(0), owner, _totalSupply);
    }


    // ------------------------------------------------------------------------
    // Total supply
    // ------------------------------------------------------------------------
    function totalSupply() public view returns (uint) {
        return _totalSupply  - balances[address(0)];
    }


    // ------------------------------------------------------------------------
    // Get the token balance for account `tokenOwner`
    // ------------------------------------------------------------------------
    function balanceOf(address tokenOwner) public view returns (uint balance) {
        return balances[tokenOwner];
    }


    // ------------------------------------------------------------------------
    // Transfer the balance from token owner's account to `to` account
    // - Owner's account must have sufficient balance to transfer
    // - 0 value transfers are allowed
    // ------------------------------------------------------------------------
    function transfer(address to, uint tokens) public returns (bool success) {
        balances[msg.sender] = balances[msg.sender].sub(tokens);
        balances[to] = balances[to].add(tokens);
        emit Transfer(msg.sender, to, tokens);
        return true;
    }


    // ------------------------------------------------------------------------
    // Token owner can approve for `spender` to transferFrom(...) `tokens`
    // from the token owner's account
    //
    // https://github.com/ethereum/EIPs/blob/master/EIPS/eip-20-token-standard.md
    // recommends that there are no checks for the approval double-spend attack
    // as this should be implemented in user interfaces
    // ------------------------------------------------------------------------
    function approve(address spender, uint tokens) public returns (bool success) {
        allowed[msg.sender][spender] = tokens;
        emit Approval(msg.sender, spender, tokens);
        return true;
    }


    // ------------------------------------------------------------------------
    // Transfer `tokens` from the `from` account to the `to` account
    //
    // The calling account must already have sufficient tokens approve(...)-d
    // for spending from the `from` account and
    // - From account must have sufficient balance to transfer
    // - Spender must have sufficient allowance to transfer
    // - 0 value transfers are allowed
    // ------------------------------------------------------------------------
    function transferFrom(address from, address to, uint tokens) public returns (bool success) {
        balances[from] = balances[from].sub(tokens);
        allowed[from][msg.sender] = allowed[from][msg.sender].sub(tokens);
        balances[to] = balances[to].add(tokens);
        emit Transfer(from, to, tokens);
        return true;
    }


    // ------------------------------------------------------------------------
    // Returns the amount of tokens approved by the owner that can be
    // transferred to the spender's account
    // ------------------------------------------------------------------------
    function allowance(address tokenOwner, address spender) public view returns (uint remaining) {
        return allowed[tokenOwner][spender];
    }


    // ------------------------------------------------------------------------
    // Token owner can approve for `spender` to transferFrom(...) `tokens`
    // from the token owner's account. The `spender` contract function
    // `receiveApproval(...)` is then executed
    // ------------------------------------------------------------------------
    function approveAndCall(address spender, uint tokens, bytes memory data) public returns (bool success) {
        allowed[msg.sender][spender] = tokens;
        emit Approval(msg.sender, spender, tokens);
        ApproveAndCallFallBack(spender).receiveApproval(msg.sender, tokens, address(this), data);
        return true;
    }


    // ------------------------------------------------------------------------
    // Don't accept ETH
    // ------------------------------------------------------------------------
    function () external payable {
        revert();
    }


    // ------------------------------------------------------------------------
    // Owner can transfer out any accidentally sent ERC20 tokens
    // ------------------------------------------------------------------------
    function transferAnyERC20Token(address tokenAddress, uint tokens) public onlyOwner returns (bool success) {
        return ERC20Interface(tokenAddress).transfer(owner, tokens);
    }
}

// File: pox-smart-contract/EthernityStorage.sol


pragma solidity ^0.5.17;

/**
 * Copyright (C) 2018, 2019, 2020 Ethernity HODL UG
 *
 * This file is part of ETHERNITY PoX SC.
 *
 * ETHERNITY PoE SC is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as
 * published by the Free Software Foundation, either version 3 of the
 * License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Affero General Public License for more details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */



contract EthernityStorage is StandardToken {

    constructor() public{
        name = "Ethernity Token TestNet";
        symbol = "tETNY";
        decimals = 18;

        _totalSupply = 1000000000 * 10 ** uint(decimals);
        balances[owner] = _totalSupply;
        emit Transfer(address(0), owner, _totalSupply);
    }

    modifier onlyOwner() {
        require(
            msg.sender == owner,
            "Only owner can call this function."
        );
        _;
    }

    address public implementation;
    address public implementationPro;

    address[] internal versions;
    address[] internal versionsPro;
    mapping(address => bool) usersPro;

    uint128 internal baseLockDate = 1688169599; // Fri Jun 30 2023 23:59:59 GMT+0000
    uint128 constant internal twoYears = 63072000;
    uint128 constant internal oneYear = 31536000;
    uint128 constant internal sixMonths = 15780000;

    mapping(address => uint128) lockTime;

    mapping(address => uint256) attestation;
    mapping(address => uint256) aggregation;
    mapping(address => uint256) proposal;

    uint16 constant internal HOURS_IN_SECONDS = 3600;
    uint8 constant internal MAX_CPU = 255;
    uint8 constant internal MAX_MEMORY = 255;
    uint8 constant internal MAX_STORAGE = 255;
    uint8 constant internal MAX_BANDWIDTH = 255;
    uint8 constant internal MAX_INSTANCES = 10;

    Models.DORequest[] internal doRequestsList;
    Models.DPRequest[] internal dpRequestsList;
    Models.Order[] internal orders;

    mapping(address => uint256[]) usersDORequests;
    mapping(address => uint256[]) usersDPRequests;
    mapping(address => uint256[]) usersOrders;
}

// File: pox-smart-contract/EthernityRegistry.sol


pragma solidity ^0.5.17;

/**
 * Copyright (C) 2018, 2019, 2020 Ethernity HODL UG
 *
 * This file is part of ETHERNITY PoX SC.
 *
 * ETHERNITY PoE SC is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as
 * published by the Free Software Foundation, either version 3 of the
 * License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Affero General Public License for more details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */


contract EthernityRegistry is EthernityStorage {

    constructor() public {
        versions.push(address(0));
        versionsPro.push(address(0));
    }


    /**
    * @dev Upgrades the implementation address
    * @param _newImplementation address of the new implementation
    */
    function upgradeTo(address _newImplementation) public onlyOwner returns (bool success){

        require(implementation != _newImplementation);
        _setImplementation(_newImplementation);
        return true;
    }

    /**
    * @dev Upgrades the implementation address
    * @param _newImplementation address of the new implementation
    */
    function upgradeToPro(address _newImplementation) public onlyOwner returns (bool success){

        require(implementationPro != _newImplementation);
        _setImplementationPro(_newImplementation);
        return true;
    }

    /**
     * @dev Fallback function allowing to perform a delegatecall
     * to the given implementation. This function will return
     * whatever the implementation call returns
     */

    function _fallback() internal {
        address target = address(0);
        if (usersPro[msg.sender] == true) {
            target = implementationPro;
        } else {
            target = implementation;
        }

        require(target != address(0));
        callerAddress = msg.sender;

        assembly {
            let ptr := mload(0x40)
            let size := and(add(calldatasize, 0x1f), not(0x1f))
            mstore(0x40, add(ptr, size))
            calldatacopy(ptr, 0, calldatasize)
            let result := delegatecall(gas, target, ptr, calldatasize, 0, 0)

            switch result
            case 0 {
                revert(0, 0)
            } default {
                let retptr := mload(0x40)
                mstore(0x40, add(retptr, returndatasize))
                returndatacopy(retptr, 0x0, returndatasize)
                return (retptr, returndatasize)
            }
        }
    }

    function() payable external {
        _fallback();
    }

    function transfer(address to, uint tokens) public returns (bool success) {
        _fallback();
    }

    function transferFrom(address from, address to, uint tokens) public returns (bool success) {
        _fallback();
    }

    function approve(address spender, uint tokens) public returns (bool success) {
        _fallback();
    }

    function approveAndCall(address spender, uint tokens, bytes memory data) public returns (bool success) {
        _fallback();
    }

    function _addProUser(address userPro) public onlyOwner returns (bool){
        usersPro[userPro] = true;
        return true;
    }

    function _removeProUser(address userPro) public onlyOwner returns (bool){
        usersPro[userPro] = false;
        return true;
    }

    function _checkProUser(address userPro) public onlyOwner view returns (bool){
        return usersPro[userPro];
    }

    /**
    * @dev Sets the address of the current implementation
    * @param _newImp address of the new implementation
    */
    function _setImplementation(address _newImp) internal onlyOwner {
        implementation = _newImp;
        versions.push(_newImp);
    }

    function _setImplementationPro(address _newImp) internal onlyOwner {
        implementationPro = _newImp;
        versionsPro.push(_newImp);
    }

    /**
    * returns true for pro users | false for community
    */
    function _checkSubscription() public view returns (bool){
        return usersPro[msg.sender];
    }
}